AMELIORATION de SWFExplorer : parcourir toutes les classes d’une librairie externe

package
{
 
	import flash.utils.ByteArray;
	import ru.etcs.utils.getDefinitionNames;
 
	import flash.display.Loader;
	import flash.net.URLRequest;
	import flash.events.Event;
	import flash.display.Sprite;
 
	import com.demonsters.debugger.MonsterDebugger;
 
	/**
	 * La classe Main qui étend Sprite.
	 *
	 * définit le nombre d'images par secondes dans les paramètres de compilation
	 * -default-frame-rate 10
	 *
	 * source : http://etcs.ru/pre/getDefinitionNamesSource/
	 *
	 */
	public class Main extends Sprite
	{		
 
		/**
		 * Constructeur.
		 */
		public function Main()
		{
			// attend la fin de l'initialisation de la scène
			this.addEventListener(Event.ADDED_TO_STAGE, onReady, false, 0, true);
		}
 
		/**
		 * Démarrage de l'application.
		 * définit le nombre d'images par secondes dans les paramètres de compilation
		 * -default-frame-rate 10
		 *
		 */
		private function onReady(event : Event) : void
		{
			this.removeEventListener(Event.ADDED_TO_STAGE, onReady);
 
			// Init De MonsterDebugger
			MonsterDebugger.initialize(this);
			MonsterDebugger.trace(this, "Start Application");
 
			loadSWF();
		}
 
		/**
		 * Chargement d'un SWF à partir d'un objet Loader.
		 *
		 */
		private function loadSWF() : void
		{
			var _loader:Loader = new Loader();
			_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onSWFLoaded );
			//var file:URLRequest =  new URLRequest("fonts.swf");
			//var file:URLRequest =  new URLRequest("ui.swf");
			var file:URLRequest =  new URLRequest("pixlib.swf");
			_loader.load(file);
		}
 
		/**
		 * SWF chargé.
		 * Récupération des définitions de classes.
		 *
		 */
		private function onSWFLoaded(event : Event) : void
		{
			MonsterDebugger.trace(this, "onSWFLoaded parse some SWF bytes");
			MonsterDebugger.trace(this, event);
 
			var libraryBytes : ByteArray = event.target.content.loaderInfo.bytes as ByteArray;
 
			// affiche toutes les classes du fichier swf
			MonsterDebugger.trace(this, getDefinitionNames(libraryBytes));
 
			// affiche toutes les classes du fichier swf avec en plus les interfaces, les vecteurs, namespace...
            MonsterDebugger.trace(this, getDefinitionNames(libraryBytes, true));
 
			// affiche seulement les classes avec un lien public (avec un linkage)
			// pratique pour récupérer les linkages graphiques de votre fichier swf
            MonsterDebugger.trace(this, getDefinitionNames(libraryBytes, true, true));
		}
 
	}
}