Parcourir toutes les classes d’une librairie externe avec SWFExplorer

package
{
 
	import flash.display.Loader;
	import flash.utils.ByteArray;
	import org.bytearray.explorer.SWFExplorer;
	import flash.net.URLRequest;
	import org.bytearray.explorer.events.SWFExplorerEvent;
	import flash.events.Event;
	import flash.display.Sprite;
 
	import com.demonsters.debugger.MonsterDebugger;
 
	/**
	 * La classe Main qui étend Sprite.
	 *
	 * définit le nombre d'images par secondes dans les paramètres de compilation
	 * -default-frame-rate 10
	 *
	 * source : http://code.google.com/p/swfexplorer/
	 *
	 */
	public class Main extends Sprite
	{
		private var oSWFexplorer : SWFExplorer;
 
		/**
		 * Constructeur.
		 *
		 */
		public function Main()
		{
			// attend la fin de l'initialisation de la scène
			this.addEventListener(Event.ADDED_TO_STAGE, onReady, false, 0, true);
		}
 
		/**
		 * Démarrage de l'application.
		 * définit le nombre d'images par secondes dans les paramètres de compilation
		 * -default-frame-rate 10
		 *
		 */
		private function onReady(event : Event) : void
		{
			this.removeEventListener(Event.ADDED_TO_STAGE, onReady);
 
			// Init De MonsterDebugger
			MonsterDebugger.initialize(this);
			MonsterDebugger.trace(this, "Start Application");
 
			// chargement d'un SWF à partir d'un objet SWFExplorer
			oSWFexplorer  = new SWFExplorer();
			oSWFexplorer.addEventListener(SWFExplorerEvent.COMPLETE, onLoadAssetsReady);
 
			//oSWFexplorer.load(new URLRequest("fonts.swf"));
			oSWFexplorer.load(new URLRequest("eaze-tween.swf"));
		}
 
		/**
		 * Chargement d'un SWF à partir d'un objet Loader.
		 *
		 */
		private function loadSWF() : void
		{
			var _loader:Loader = new Loader();
			_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onSWFLoaded );
			var file:URLRequest =  new URLRequest("fonts.swf");
			_loader.load(file);
		}
 
		/**
		 * SWF chargé.
		 * Récupération des définitions de classes.
		 *
		 */
		private function onSWFLoaded(event : Event) : void
		{
			MonsterDebugger.trace(this, "onSWFLoaded parse some SWF bytes");
			MonsterDebugger.trace(this, event);
 
			var libraryBytes : ByteArray = event.target.content.loaderInfo.bytes as ByteArray;
			var definitions:Array = oSWFexplorer.parse(libraryBytes);
 
			MonsterDebugger.trace(this,  "definitions ");
			// renvoie un tableau contenant les définitions des classes
			MonsterDebugger.trace(this,  definitions );
 
			// renvoie un tableau contenant les définitions des classes
			MonsterDebugger.trace(this,  oSWFexplorer.getDefinitions() );
 
			// affiche le nombre de classes
			MonsterDebugger.trace(this, oSWFexplorer.getTotalDefinitions());
		}
 
		/**
		 * SWF chargé par SWFExplorer.
		 * Récupération des définitions de classes.
		 *
		 */
		private function onLoadAssetsReady(e : SWFExplorerEvent) : void
		{
			oSWFexplorer.removeEventListener(SWFExplorerEvent.COMPLETE, onLoadAssetsReady);
 
			MonsterDebugger.trace(this, "onLoadAssetsReady");
			MonsterDebugger.trace(this, e);
 
			// renvoie un tableau contenant les définitions des classes
			MonsterDebugger.trace(this, e.definitions);
 
			// renvoie un tableau contenant les définitions des classes
			MonsterDebugger.trace(this, e.target.getDefinitions());
 
			// affiche le nombre de classes
			MonsterDebugger.trace(this, e.target.getTotalDefinitions());
 
			loadSWF();
		}
 
	}
}