<h2>Votre Formation vidéo</h2><br/>
Votre formation est décomposée<br/>
en chapitres très clairs de 20 à 30 min. <h2>Des exemples SWF </h2><br/>
Chaque leçon est accompagnée<br/>
du code source avec le fla et les classes. <h2>Votre Suivi personnalisé</h2><br/>
Vous pouvez  me poser toutes<br/>
vos questions sous les cours vidéos.

Utiliser n’importe quelle classe ActionScript comme un Singleton

Commentaires fermés sur Utiliser n’importe quelle classe ActionScript comme un Singleton

Écrit le 7 février par Matthieu
Publié dans le(s) sujet(s) ActionScript 3

Mots clés : , ,

Le Kit du Développeur Flash

Vous connaissez sûrement le Pattern Singleton, un des tout premiers que l’on découvre.

Suivant le projet flash sur lequel vous travaillez, il est possible que vous ayez besoin de transformer une de vos classes en Singleton.

Toutefois, vous ne voulez pas modifier le code source de la classe, pour conserver l’architecture de votre Framework AS3.

J’ai déniché une petite classe utilitaire qui permet de “transformer” n’importe quelle classe ActionScript en Singleton.

Par exemple, dans une application flash quelconque, vous souhaitez toujours utiliser la même instance de l’objet Point, ou une seule instance TextField. Et cela, sans utiliser de variable pour stocker cette référence.

La classe net.richardlord.utils.Singleton.as s’assure qu’une seule instance de la classe, spécifiée en paramètre, existe dans toute l’application flash.

Cette classe Singleton utilise la classe Dictionary qui permet d’associer une clé à une valeur.

En l’occurrence, la clé correspond au nom de la classe, et la valeur contient l’instance de la classe.

Le gros intérêt de cette classe est de permettre de limiter à une instance unique n’importe quelle classe ActionScript, sans modifier son code !

Exemple Singleton Classes

Et voici un exemple est plus parlant.

Il s’agit de créer un objet TextField, sans sauvegarder son instance dans une variable de classe.

Puis plus loin dans une fonction de la classe, nous modifions le contenu du TextField, en utilisant la classe singleton.

/**
 
  The Initial Developer of the Original Code is
  Matthieu  - https://www.actionscript-facile.com
  Portions created by the Initial Developer are Copyright (C) 2010
  the Initial Developer. All Rights Reserved.
 
  Contributor(s) :
 
 */
package
{
	import flash.text.TextFormat;
	import flash.text.TextFieldAutoSize;
	import net.richardlord.utils.Singleton;
	import flash.text.TextField;
	import flash.events.Event;
	import flash.display.Sprite;
 
	import com.demonsters.debugger.MonsterDebugger;
 
	public class Main extends Sprite
	{
 
		/**
		 * Constructeur.
		 *
		 */
		public function Main()
		{
			// attend la fin de l'initialisation de la scène
			this.addEventListener(Event.ADDED_TO_STAGE, onReady, false, 0, true);
		}
 
		/**
		 * Démarrage de l'application.
		 * définit le nombre d'images par secondes dans les paramètres de compilation
		 * -default-frame-rate 40
		 *
		 */
		private function onReady(event : Event) : void
		{
			this.removeEventListener(Event.ADDED_TO_STAGE, onReady);
 
			// Init De MonsterDebugger
			MonsterDebugger.initialize(this);
			MonsterDebugger.trace(this, "Start Application");
 
			this.addText();
 
			var txtField:TextField = Singleton( TextField );
			this.addChild(txtField);
 
			this.updateText("Mise à jour du champ texte avec la classe Singleton !");
		}
 
		/**
		 * Création d'un champ texte.
		 *
		 */
		private function addText() : void
		{
			 var txtField:TextField = Singleton( TextField );
		     txtField.text = "Texte d'initilisation...";
		     txtField.autoSize = TextFieldAutoSize.LEFT;
		     txtField.textColor = 0x006f77;
		     txtField.selectable = false;
		 	 txtField.x = 33;
			 txtField.y = 163;
 
		     // définit le format par défaut du texte
		     var format : TextFormat = new TextFormat();
		     format.size = 21;
		     format.font = "Arial";
		     txtField.defaultTextFormat = format;
		}
 
		/**
		 * Mise à jour du champ texte
		 * en utilisant la classe singleton
		 *
		 */
		private function updateText(sValue:String) : void
		{
			var txtField:TextField = Singleton( TextField );
			 txtField.text = sValue;
		}
 
	}
}
Singleton   
/*
 * Author: Richard Lord
 * Copyright (c) Richard Lord 2007
 * http://www.richardlord.net/blog/singleton-factory
 *
 * Licence Agreement (The MIT License)
 *
 * Permission is hereby granted, free of charge, to any person obtaining a copy
 * of this software and associated documentation files (the "Software"), to deal
 * in the Software without restriction, including without limitation the rights
 * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 * copies of the Software, and to permit persons to whom the Software is
 * furnished to do so, subject to the following conditions:
 *
 * The above copyright notice and this permission notice shall be included in
 * all copies or substantial portions of the Software.
 *
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
 * THE SOFTWARE.
 */
package net.richardlord.utils
{
	/**
	 * Returns the same instance of a class every time. If necessary, it creates an instance.
	 *
	 * Usage -
	 * var a:SomeClass = singleton( SomeClass );
	 */
	public function Singleton( type : Class ) : *
	{
		return type in instances ? instances[type] : instances[type] = new type();
	}
}
 
import flash.utils.Dictionary;
var instances : Dictionary = new Dictionary( false );

SWF Démonstration Singleton Classes

Et voici le swf basique pour illustrer l’utilisation de cette classe Singleton.

https://www.actionscript-facile.com/wp-content/uploads/2012/02/singleton-classes.swf

Télécharger le code source Singleton

Visiter le site de l’auteur : Richard Lord

Télécharger “Singleton Classes” ex-singleton-classes.zip – Téléchargé 75 fois – 75 KB

Utilisez-vous des classes utilitaires pour vous simplifier la programmation ActionScript ?

Partagez-les avec les Développeurs AS3 Facile, via les commentaires ci-dessous.



Développez des Jeux et Applications Flash avec la Formation AS3 Facile !

Recevez Gratuitement Des Cours en Vidéos, des codes source et des livrets de formation.
Et en bonus gratuit : Le Framework AS3 Facile ! 


porta. Phasellus vel, Donec non leo. Praesent odio mi, dolor quis,